Public Class DataClass
 
    Private _name As String
 
    Public Property Name() As String
        Get
            return Me._name
        End Get
        Set(ByVal value As String)
            Me._name = value
        End Set
    End Property
 
End Class

' ###
' Example 1: Interface (The way I would program with Java)
 
Public Interface IDataClassListener
 
    Sub OnNameChange(ByVal d As DataClass)
 
End Interface
 
Public Class DataClass
 
    ' Add a list of listeners for this object
    Private _listeners As New List(Of IDataClassListener)
    Private _name As String
 
    Public Property Name() As String
        Get
            return Me._name
        End Get
        Set(ByVal value As String)
            Me._name = value
            RaiseOnNameChange() ' Raise the event
        End Set
    End Property
 
    ' Method to add a listener to the object,
    ' there would be a remove listener method also
    Public Sub AddListener(ByVal listener As IDataClassListener)
        Me._listeners.Add(listener)
    End Sub
 
    ' Method to raise the method on all listening objects
    Private Sub RaiseOnNameChange()
        For Each listener As IDataClassListener In me._listeners
            listener.OnNameChange(Me)
        Next
    End Sub
 
End Class
 
' Then in my form I could implement the interface and 
' assign it as a listener on the object
Public Class MyForm
    Implements IDataClassListener
 
    Private _data As DataClass
 
    Public Sub New(ByVal data As DataClass)
        Me._data = data
        Me._data.AddListener(Me)
    End Sub
 
    Private Sub OnNameChange(ByVal d As DataClass) Implements IDataClassListener.OnNameChange
        ' ### Update the display on change
    End Sub
 
End Class

' ###
' Example 2: Event Driven
 
Public Class DataClass
 
    Delegate Sub OnNameChangeHandler(ByVal d As DataClass)
    Public Event OnNameChange As OnNameChangeHandler
    Private _name As String
 
    Public Property Name() As String
        Get
            return Me._name
        End Get
        Set(ByVal value As String)
            Me._name = value
            RaiseEvent Me.OnNameChange(Me) ' Raise the event
        End Set
    End Property
 
End Class
 
' Different from example 1, just add a handler to the event
Public Class MyForm
 
    Private _data As DataClass
 
    Public Sub New(ByVal data As DataClass)
        Me._data = data
        Dim d As New DataClass.OnNameChangeHandler(AddressOf Me.OnNameChange)
        AddHandler _data.OnNameChange, d
    End Sub
 
    Private Sub OnNameChange(ByVal d As DataClass)
        ' ### Update the display on change
    End Sub
 
End Class