Make a MDI Form borderless

-1

By sidnei on Dec 31st, 2009 3:15 am

This code show how to made a MDI Form Borderless.
Tested on Visual Basic 6 under Windows XP SP3 platform.

'This is the API declaration; I suggest to put it in a module, OR change private to public
Private Declare Function GetWindowLong Lib "USER32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "USER32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long


'Constants to make code more readable
Private Const GWL_STYLE = (-16)
Private Const WS_BORDER = &H800000
Private Const WS_CAPTION = &HC00000


'A generic function to make a form borderless
Public Sub RetiraBorda(ByRef nFormHWND As Long)

  Dim nEstilo As Long
  
  
  On Error GoTo errRetiraBorda
  
  nEstilo = GetWindowLong(nFormHWND, GWL_STYLE)
  nEstilo = nEstilo And Not WS_CAPTION
  SetWindowLong nFormHWND, GWL_STYLE, nEstilo

Exit Sub

errRetiraBorda:
  MsgBox "Erro na execução da rotina:" & vbNewLine & vbNewLine & Err.Number & " - " & Err.Description, vbExclamation, "RetiraBorda"

End Sub


'The function can be called this way, in the form for example
Private Sub MDIForm_Activate()

  Dim rTela As tCoord
  
  RetiraBorda Me.hwnd
  rTela = AreaTrabalho
  
  'Some other code to initialize application
  '(...)

End Sub

1 Year Ago

could you to tell us what your Project Component and Project References
B'cause I get error on descr below

Dim rTela As tCoord

labq5

Newbie Poster

11 posts since Apr 2010

Reputation Points: 10

Solved Threads: 0

1 Year Ago

@labq5, There are easier ways to make your form borderless. You do however need to open a new thread of your own. This was only a code snippet from 2009, I doubt it if anyone will answer your question.

I'll reply on your new thread once it is open.:)

AndreRet

Senior Poster

3,922 posts since Jan 2008

Reputation Points: 334

Solved Threads: 350

1 Year Ago

Show Comments

Hi, labq5

Sorry for this mistake...
tCoord is a structure I define in a module:

'TIPOS DE DADOS NECESSARIOS
Type tCoord
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

It holds the information of my desktop bounds, this way I can resize my form to the max available space on the screen without covering the taskbar (if you maximize a borderless form, it will cover the taskbar, and I hate this behaviour!).

The AreaTrabalho function performs the calculation of available desktop area, as I mentioned before.
Here is the code for that function:

Public Function AreaTrabalho() As tCoord
 
  Dim rCoord As tCoord
 
 
  On Error GoTo errAreaTrabalho
 
  If SystemParametersInfo(48, vbNull, rCoord, 0) Then
    AreaTrabalho = rCoord
  End If
 
  Exit Function
 
errAreaTrabalho:
  MsgBox "Erro na execução da rotina:" & vbNewLine & vbNewLine & Err.Number & " - " & Err.Description, vbExclamation, "AreaTrabalho"
 
End Function

Both declarations (the structure and the function) are typed in a module, this way it can be used for any form in your application.

In addition, all code showed in the original post can be put in a module, only the piece "MDIForm_Activate()" should be on form's activate event, AND YOU NEED to declare this API function too:

Private Declare Function SystemParametersInfo Lib "USER32" Alias "SystemParametersInfoA" (ByVal uAction As Long, ByVal uParam As Long, lpvParam As Any, ByVal fuWinIni As Long) As Long

(make it on the same module you put the function into)

Hope it helps!
Sidnei

sidnei

Junior Poster in Training

55 posts since Dec 2009

Reputation Points: 22

Solved Threads: 10

1 Year Ago

Show Comments

Hi, AndreRet!

This is an older post, I agree...
But I reply to it cause I have a extremely dificult to find ANY information on how to put a MDI form borderless.

Do you know a way to do it more simpler? Note that I'm using VB6 under Windows XP, and it's not a common form, but a MDI form, the one that doesn't have the "BorderStyle" property to be set on the properties window...

Can you put a link or piece of code to show how to make this task easier?
I know it's an older thread, but I'm really interested...

Best regards,
Sidnei

sidnei

Junior Poster in Training

55 posts since Dec 2009

Reputation Points: 22

Solved Threads: 10

1 Year Ago

No problem, I'll post it tomorrow, time for my daily beer.;)

AndreRet

Senior Poster

3,922 posts since Jan 2008