Converting various video formats to mp4

'                                                                                       '
'   Name:                                                                               '
'                                                                                       '
'       cv.vbs                                                                          '
'                                                                                       '
'   Description:                                                                        '
'                                                                                       '
'       Converts various video formats to mp4. Specify the file(s) to convert on the    '
'       command line or drag and drop a file onto a shortcut to this script. Ffmpeg is  '
'       used to do the actual conversion. Currently supported input formats are flv     '
'       and avi. Conversion is done while maintaining the quality of the ooriginal      '
'       file. In the case of flv files, all that is really required is a repackaging    '
'       of the flv into an mp4 wrapper. As such, conversion takes just a few seconds.   '
'       On the other hand, avi files require a complete conversion so converting even   '
'       a one hour video could take up to 30 minutes.                                   '
'                                                                                       '
'       Currently, when I try to ChromeCast avi or flv (by dropping onto a Chrome       '
'       session, all that happens is that the file is downloaded from one folder into   '
'       my "downloads" folder. Onlt mp4 files play properly. Until the next major       '
'       release of vlc media player (which is supposed to support direct casting to     '
'       ChromeCast) I'll have to convert.                                               '
'                                                                                       '
'		Note: when specifying a filename on the command line, wildcards "*" and "?"     '
'       may be used to convert more than one file at a time.                            '
'                                                                                       '
'   Audit:                                                                              '
'                                                                                       '
'		2016-01-24	rj	added time stamp to file name output & added mkv option			'
'       2015-10-13  rj  original code                                                   '
'                                                                                       '

'Template ffmpeg commands for various input formats. FILE will be replaced with the		'
'video file name without the extension. To add more formats add another dictionary     	'
'entry with the extension as the key and the value as the ffmpeg command.               '

set cmds = CreateObject("Scripting.Dictionary")

cmds.Add "avi", "ffmpeg -y -i ""FILE.avi"" -c:v libx264 -crf 17 -preset slow -c:a aac -strict -2 -b:a 192k -ac 2 ""FILE.mp4"""
cmds.Add "flv", "ffmpeg -y -i ""FILE.flv"" -vcodec copy -acodec copy ""FILE.mp4"""
cmds.Add "mkv", "ffmpeg -y -i ""FILE.mkv"" -vcodec copy -acodec copy ""FILE.mp4"""

'Create worker objects

set fso = CreateObject("Scripting.FileSystemObject")
set wso = CreateObject("Wscript.Shell")	
set arg = Wscript.Arguments

'If no arguments then show brief help

if arg.Count = 0 Then
	help = "\n" _
	     & "cv filename\n\n" _
	     & "  Convert video file(s) to mp4. * and ? wildcards supported.\n"   _
	     & "  Current input formats are avi, flv & mkv. Existing output files\n" _
	     & "  will be overwritten."
	Wscript.Echo Replace(help,"\n",vbCrLf)
	Wscript.Quit
end if

'Set working directory to input file folder

path = fso.GetParentFolderName(arg(0))
if path <> "" then wso.CurrentDirectory = path

'Generate all matching file names. This is done by executing the shell DIR
'command and grabbing the output. Doing this lets me pass off the wildcard
'processing to DIR rather than doing it myself with a regular expression.

set dir = wso.Exec("cmd /c dir """ & fso.GetFileName(arg(0)) & """ /b")

do	'process all matching files

	start = Now

	file = dir.StdOut.ReadLine			'file name from dir command '
	base = fso.GetBaseName(file)		'file name with no extension'
	extn = fso.GetExtensionName(file)	'file extension             '
	
	'convert known formats
	
	if cmds.Exists(extn) Then
		Execute "Convert Replace(cmds(extn),""FILE"",base)"
		Progress "  Elapsed time " & TimeSerial(0,0,DateDiff("s",start,Now))
	else
		Wscript.Echo extn & " format not supported"
		Pause			
	End If
	
loop until dir.StdOut.AtEndOfStream

'Pause script if running in Windowed mode (from drag & drop)

Function Pause
	if Windowed Then
		Wscript.Echo "Press enter to continue"
		Wscript.StdIn.ReadLine
	End If
End Function

'Show progress if running in non-Windowed (command line) mode

Function Progress (text)
	If not Windowed Then
		Wscript.Echo text
	end if
End Function

'Returns True if running in Windowed (drag & drop) mode

Function Windowed
	Windowed = instr(1,Wscript.FullName,"wscript",1) > 0
End Function

'Run the ffmpeg conversion command in a separate visible thread and wait.

Function Convert (cmd)
	wso.Run cmd, 1, True
End Function