Printing text with word wrap

Imports System.IO

Public Class Form1

    Private pf As New Font("Arial", 10)     'this font will be used for the print
    Private sr As StreamReader

    Private Sub btnPrint_Click(sender As System.Object, e As System.EventArgs) Handles btnPrint.Click

        Try
            sr = New StreamReader("D:\My Documents\History of the Amiga.txt")
            Try
                pd.Print()
            Finally
                sr.Close()
            End Try
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try

    End Sub

    'The PrintPage event is raised for each page to be printed. This Sub will handle
    'word wrap. It does this by parsing each line into blank delimited tokens and   
    'calculating the pront position of each token. If the current token will not fit
    'on the current line then a new line is started. Note that this sub will not    
    'handle a line with no blanks that is wider than the page printable width.      

    Private Sub pd_PrintPage_1(sender As System.Object, e As System.Drawing.Printing.PrintPageEventArgs) Handles pd.PrintPage

        Dim linesPerPage As Integer     'number of lines that will fit on a page    
        Dim yPos As Single = 0          'y position of the next line to print       
        Dim lineNum As Integer = 0      'the current line number                    
        Dim line As String = Nothing    'next line from text file                   

        'these must be declared as Static to preserve their values between calls    

        Static xPos As Single = 0       'x position of the next token to print      
        Static tokens() As String       'current line tokenized by blanks           
        Static tokidx As Single = -1    'index of next token to print               

        ' Calculate the number of lines per page.

        linesPerPage = e.MarginBounds.Height / pf.GetHeight(e.Graphics)

        ' Print each line of the file. 

        While lineNum < linesPerPage

            'if we are not continuing with unused tokens from the previous line     
            'then read a new line and parse it                                      

            If tokidx = -1 Then
                line = sr.ReadLine()                    'read a new line            
                If line Is Nothing Then Exit While
                xPos = e.MarginBounds.Left              'reset to left margin       
                tokens = line.Split()                   'parse the new line         
                tokidx = 0                              'reset token index          
            End If

            yPos = e.MarginBounds.Top + lineNum * pf.GetHeight(e.Graphics)

            'print all tokens

            While tokidx < tokens.Length

                'get the next token and calculate the required width

                Dim token As String = tokens(tokidx) & " "
                Dim w As SizeF = e.Graphics.MeasureString(token, pf)

                'if the token will fit on the current line then render it otherwise 
                'reset xpos to the left margin and start a new line                 

                If w.Width + xPos <= e.MarginBounds.Right Then
                    e.Graphics.DrawString(token, pf, Brushes.Black, New Point(xPos, yPos))
                    xPos += w.Width
                    tokidx += 1
                Else
                    xPos = e.MarginBounds.Left
                    Exit While
                End If

            End While

            'if all tokens have been processed then reset the index to -1 to force  
            'a read of a new line                                                   

            If tokidx = tokens.Length Then tokidx = -1
            lineNum += 1

        End While

        ' If more lines exist, print another page.

        e.HasMorePages = (line IsNot Nothing)

    End Sub

End Class